Exult Forum

Code: Select all

void FunName shape#(shapeid) ()

Code: Select all

#include "headers/constants.uc"					//standard constant definitions
#include "headers/constants2.uc"				//standard constant definitions

#include "headers/bg/bg_npcs.uc"				//Black Gate npc constants
#include "headers/npcs.uc"						//New npc constants

#include "headers/bg/bg_shapes.uc"				//Black Gate shape and frame constants
#include "headers/bg/bg_shapes2.uc"				//Black Gate shape and frame constants
#include "headers/new_shapes.uc"				//Brand new shape and frame constants

#include "headers/bg/bg_gflags.uc"				//Black Gate global flags
#include "headers/bg/bg_gflags2.uc"				//Black Gate global flags
#include "headers/new_flags.uc"					//Brand new global flags

#include "headers/bg/bg_externals.uc"			//extern declarations for BG functions
#include "headers/bg/bg_externals2.uc"			//extern declarations for BG functions

#include "headers/new_items.uc"					//extern declarations for new items

#include "headers/functions.uc"					//new general-purpose functions
#include "headers/functions2.uc"				//Some new general-purpose functions
#include "headers/array_functions.uc"			//Several array functions

void turnKey ()
{
	var target_frame = item->get_item_frame();
	if (((target_frame + 1) % 4) == 0)
	{
		script AVATAR
		{	actor frame 3;		wait 2;		actor frame standing;	}
		UI_play_sound_effect(SOUND_KEY);
		var unlock_frame = (target_frame - 3);
		item->set_item_frame(unlock_frame);
		return;
	}
	else
	{
		script AVATAR
		{	actor frame 3;		wait 2;		actor frame standing;	}
		randomPartyBark("@The key does not fit.@");
		return;
	}
}

void SkullKey shape#(0x400) ()
{
	if (event == DOUBLECLICK)
	{
		UI_close_gumps();
		var target = UI_click_on_item();
		if (!target)
		{
			randomPartyBark("@There is no lock on that.@");
			return;
		}
		var target_coords = getClickPosition(target);
		var lock_shapes = [SHAPE_DOOR_HORIZONTAL, SHAPE_DOOR_VERTICAL, SHAPE_DOOR2_HORIZONTAL, SHAPE_DOOR2_VERTICAL, SHAPE_CHEST, SHAPE_LOCKED_CHEST];
		var target_shape = target->get_item_shape();
		var target_frame = target->get_item_frame();
		if (!(UI_is_dest_reachable(AVATAR, target_coords)))
		{	
			UI_flash_mouse(2);
			return;
		}
		else if (target_shape in lock_shapes)
		{
			UI_si_path_run_usecode(AVATAR, target_coords, false, target, turnKey, false);
			return;
		}
		else
		{
			randomPartyBark("@There is no lock on that.@");
			return;
		}
	}
}

void RubberDucky shape#(0x401) ()
{
	if (event == DOUBLECLICK)
	{
		item->item_say("Squeak!");
		return;
	}
}

void HornOfPlenty shape#(0x402) ()
{
	if (event == DOUBLECLICK)
	{	
		var target = UI_click_on_item();
		var party = UI_get_party_list();
		if (!target)
		{
			UI_flash_mouse(1);
			return;
		}
		else if (!(target in party))
		{
			UI_flash_mouse(1);
			return;
		}
		else
		{
			var targetfood = (target->get_npc_prop(9));
			if (targetfood > 24)
			{
				target->item_say("@No, thank thee.@");
				return;
			}
			else
			{
				target->set_npc_prop(9, (31-targetfood));
				target->item_say("@Ahh, I am full now.@");
				return;
			}
		}
	}
}

void ChaosSword shape#(0x403) ()
{
	var wielder = UI_get_container(ChaosSword);
	if (event == WEAPON)
	{
		wielder->set_item_flag(2);
		return;
	}
	else if (event == READIED)
	{
		wielder->set_item_flag(2);
		UI_set_attack_mode(wielder, 0);
		return;
	}
}

void Dupre object#(0x404) ()
{
	item.say("@Nice rubber ducky thou dost have there!@");
	Dupre.original();
}

Code: Select all

#game "blackgate"
#autonumber 0xC00